[Asterisk-Users] Aastra 480e phone ADSI config

[Steve Woolley]

There isn't much documentation on adsi, but I called NETXUSA (the vendor
of my 480e) and they helped me along.
 
My experience:
 
1. I really had no experience with ADSI so I had (probably still have)
some misconceptions on how the configuration is loaded onto the phone.
 
2. I set the following in my /etc/asterisk/asterisk.adsi (most of this
is the stock asterisk.adsi script):
 
; ---------------------------------------------------------
; Asterisk default ADSI script
; ---------------------------------------------------------;
; Begin with the preamble requirements
;
DESCRIPTION "Asterisk PBX"             ; Name of vendor
VERSION 0x00                           ; Version of stuff
;SECURITY "_AST"                       ; Security code
SECURITY 0x9BDBF7AC                    ; Security code
FDN 0x0000000F                         ; Descriptor number
In an ADSI script for the 2nd Slot:
;
; Asterisk default ADSI script
;
;
; Begin with the preamble requirements
;
DESCRIPTION "Asterisk PBX"             ; Name of vendor
VERSION 0x00                           ; Version of stuff
;SECURITY "_AST"                       ; Security code
SECURITY 0x78921D49                    ; Security code
FDN 0x85EFD9DA                         ; Descriptor number
;
; Flags
;
FLAG "nocallwaiting"
 
;
; Predefined strings
;
DISPLAY "titles" IS "-- My PBX --"
DISPLAY "talkingto" IS "Call active." JUSTIFY LEFT
DISPLAY "callname" IS "$Call1p" JUSTIFY LEFT
DISPLAY "callnum" IS "$Call1s" JUSTIFY LEFT
DISPLAY "incoming" IS "Incoming call!" JUSTIFY LEFT
DISPLAY "ringing" IS "Calling... " JUSTIFY LEFT
DISPLAY "callended" IS "Call ended." JUSTIFY LEFT
DISPLAY "missedcall" IS "Missed call." JUSTIFY LEFT
DISPLAY "busy" IS "Busy." JUSTIFY LEFT
DISPLAY "reorder" IS "Reorder." JUSTIFY LEFT
DISPLAY "cwdisabled" IS "Callwait disabled"
DISPLAY "empty" IS "asdf"
 
;
; Begin soft key definitions
;
KEY "callfwd" IS "CallFwd" OR "Call Forward"
        OFFHOOK
        VOICEMODE
        WAITDIALTONE
        SENDDTMF "*60"
        GOTO "offHook"
ENDKEY
 
KEY "vmail_OH" IS "VMail" OR "Voicemail"
        OFFHOOK
        VOICEMODE
        WAITDIALTONE
        SENDDTMF "8500"
ENDKEY
 
KEY "vmail" IS "VMail" OR "Voicemail"
        SENDDTMF "8500"
ENDKEY
 
KEY "backspace" IS "BackSpc" OR "Backspace"
        BACKSPACE
ENDKEY
 
KEY "cwdisable" IS "CWDsble" OR "Disable Call Wait"
        SENDDTMF "*70"
        SETFLAG "nocallwaiting"
        SHOWDISPLAY "cwdisabled" AT 4
        TIMERCLEAR
        TIMERSTART 1
ENDKEY
 
KEY "cidblock" IS "CIDBlk" OR "Block Callerid"
        SENDDTMF "*67"
        SETFLAG "nocallwaiting"
ENDKEY
 
;
; Begin main subroutine
;
 
SUB "main" IS
        IFEVENT NEARANSWER THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1 NOUPDATE
                SHOWDISPLAY "talkingto" AT 2 NOUPDATE
                SHOWDISPLAY "callname" AT 3
                SHOWDISPLAY "callnum" AT 4
                GOTO "stableCall"
        ENDIF
        IFEVENT OFFHOOK THEN
                CLEAR
                CLEARFLAG "nocallwaiting"
                CLEARDISPLAY
                SHOWDISPLAY "titles" AT 1
                SHOWKEYS "vmail"
                SHOWKEYS "cidblock"
                SHOWKEYS "cwdisable" UNLESS "nocallwaiting"
                GOTO "offHook"
        ENDIF
        IFEVENT IDLE THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1
                SHOWKEYS "vmail_OH"
        ENDIF
        IFEVENT CALLERID THEN
                CLEAR
;               SHOWDISPLAY "titles" AT 1 NOUPDATE
;               SHOWDISPLAY "incoming" AT 2 NOUPDATE
                SHOWDISPLAY "callname" AT 3 NOUPDATE
                SHOWDISPLAY "callnum" AT 4
        ENDIF
        IFEVENT RING THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1 NOUPDATE
                SHOWDISPLAY "incoming" AT 2
        ENDIF
        IFEVENT ENDOFRING THEN
                SHOWDISPLAY "missedcall" AT 2
                CLEAR
                SHOWDISPLAY "titles" AT 1
                SHOWKEYS "vmail_OH"
        ENDIF
        IFEVENT TIMER THEN
                CLEAR
                SHOWDISPLAY "empty" AT 4
        ENDIF
ENDSUB
 
SUB "offHook" IS
        IFEVENT FARRING THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1 NOUPDATE
                SHOWDISPLAY "ringing" AT 2 NOUPDATE
                SHOWDISPLAY "callname" at 3 NOUPDATE
                SHOWDISPLAY "callnum" at 4
        ENDIF
        IFEVENT FARANSWER THEN
                CLEAR
                SHOWDISPLAY "talkingto" AT 2
                GOTO "stableCall"
        ENDIF
        IFEVENT BUSY THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1 NOUPDATE
                SHOWDISPLAY "busy" AT 2 NOUPDATE
                SHOWDISPLAY "callname" at 3 NOUPDATE
                SHOWDISPLAY "callnum" at 4
        ENDIF
        IFEVENT REORDER THEN
                CLEAR
                SHOWDISPLAY "titles" AT 1 NOUPDATE
                SHOWDISPLAY "reorder" AT 2 NOUPDATE
                SHOWDISPLAY "callname" at 3 NOUPDATE
                SHOWDISPLAY "callnum" at 4
        ENDIF
ENDSUB
 
SUB "stableCall" IS
        IFEVENT REORDER THEN
                SHOWDISPLAY "callended" AT 2
        ENDIF
ENDSUB
; ---------------------------------------------------------
; End Asterisk default ADSI script
; ---------------------------------------------------------;

3. I only had to tune the SENDDTMF "8500" values to properly send it to
the right voicemain extention

4. Added the following to my /etc/asterisk/extensions.conf file in a
local only context so that the phone could only be programmed locally:

[adsi-program]
exten => 9666,1,Authenticate(1234)
exten => 9666,2,ADSIProg(asterisk.adsi)
exten => 9666,3,Hangup

5. Called extension 9666 from the 480e. It asks for my password and then
I am off to the races.

Good luck!

________________________________

	From: asterisk-users-admin at lists.digium.com
[mailto:asterisk-users-admin at lists.digium.com] On Behalf Of Martin
Keding
	Sent: Wednesday, July 28, 2004 5:44 PM
	To: asterisk-users at lists.digium.com
	Subject: [Asterisk-Users] Aastra 480e phone ADSI config
	
	
	Greetings
	 
	Does anyone have a ADSI config file for an Astra (Sayson) 480e
phone. I am using the sample asterisk.adsi file but if anyone already
has a modified working file that they would like to share, could you let
me know.
	 
	Thanks
	Martin